Changing the PWM phase

[coderatchance]

Hello All!

I am trying to run two PWMs sequentially, however, I would like to adjust their phase, namely inverting.

I guess this can be done with the analogWrite()?
Such as analogWrite(brightness, myLedPin);

For example, I took a shot with fading two leds to get the visuals...
However, the whole fading concept does not work...
For one led, namely brightness, it works well, it goes up and down.
While for the brightness2 I can not figure out the "phase adjustment", namely to start latter...

As it can been seen below I have used the simple if().
Brightness starts inphase, while the brightness2 should be 180 degrees out of phase?
For example, when brightness is 0, the brightness2 is 255,
and the opposite, when brightness2 = 255, brightness = 0.

Anyway, here is the code:

void fading1() {
  //in both cases the fadeAmount = 1

  // brightness
  brightness = brightness + fadeAmount;

  //brightness
  // start at min got o max and go back min and so fort
  // 0 < 25 > 0
  if (brightness <= 0 or brightness >= 255) {
    fadeAmount =- fadeAmount;
  }

  //brightness2
  //starting at max=25?
  brightness2 = brightness2 - fadeAmount2;

  // start at max go to min and go back to max and so fort
  //25 > 0 < 25
  if (brightness2 <= 0 or brightness2 >= 255) {
    fadeAmount2 =+ fadeAmount2;
  }

  Serial.print("  ");
  Serial.print(brightness);
  Serial.print("  ");
  Serial.print(brightness2);
  Serial.println();

}

Any ideas how to tackle this would be very appreciated !

Best.

PS: would a simple delay() do the trick?

[hmeijdam]

Does it require dead-time as for when you are driving a H-bridge, or is some overlap at the moment of switching ok?

[hmeijdam]

You could use the CCL for outputting the PWM output of one of the timers to another pin and invert it while doing so.

Below example (Attiny412) outputs WO2 on PA2 and then the CCL also outputs that PWM signal inverted on PA6.
As a result you can see a led on PA2 fading out and a led on PA6 fading in.

void setup() {
  // No need to enable split mode - core has already done that for us.
  pinModeFast (PIN_PA1, OUTPUT);
  pinModeFast (PIN_PA2, OUTPUT);
  pinModeFast (PIN_PA3, OUTPUT);
  pinModeFast (PIN_PA7, OUTPUT);
  pinModeFast (PIN_PA6, OUTPUT);
  TCA0_SPLIT_CTRLB  = TCA_SPLIT_HCMP0EN_bm |  TCA_SPLIT_LCMP1EN_bm | TCA_SPLIT_LCMP0EN_bm; // WO0, WO1 and WO3 on

  TCA0_SPLIT_CTRLB |= TCA_SPLIT_LCMP2EN_bm;// uncomment to also get WO2 output on PA2. Comment for only PA6 output.

  TCA0_SPLIT_LPER   = 255; // Count all the way down from 255 on WO0/WO1/WO2
  TCA0_SPLIT_HPER   = 170;  // Count down from only 170 on WO3, giving higher frequency PWM with lower resolution
  TCA0_SPLIT_CTRLA  = TCA_SPLIT_CLKSEL_DIV64_gc | TCA_SPLIT_ENABLE_bm; // enable the timer with prescaler of 64

  // Use CCL to (also) redirect the WO2 output to PA6
  CCL_LUT0CTRLB = 0; // nothing needed for the first two LUT input channels
  CCL_LUT0CTRLC = 0x08; // connect TCA0 WO2 input into the third LUT input channel
  // CCL_TRUTH0 = (1<<4); // TRUE when third LUT channel is TRUE ('b100') (non-inverted output)
  CCL_TRUTH0 = (1 << 0); // TRUE when third LUT channel is FALSE ('b001') (inverted output)
  CCL_LUT0CTRLA = CCL_OUTEN_bm | CCL_ENABLE_bm; // enable LUT0 output pin (PA6) and enable LUT0
  CCL_CTRLA = CCL_ENABLE_bm;// enable the whole CCL peripheral
}

void loop() { // nothing to do here
  static uint8_t pwm_value = 0;
  TCA0_SPLIT_LCMP0  = pwm_value; // Lowbyte timer dutycycle WO0 on PA7
  TCA0_SPLIT_LCMP1  = pwm_value + 85; // Lowbyte timer dutycycle WO1 on PA1
  TCA0_SPLIT_LCMP2  = pwm_value + 170; // Lowbyte timer dutycycle WO2 on PA2
  TCA0_SPLIT_HCMP0  = pwm_value / 3 * 2 ; // Highbyte timer dutycycle WO3 on PA3
  pwm_value--;
  delay(10);
}