Jenkinsfile.internal

/**
 * SPDX-FileCopyrightText: 2015-2024 tracetronic GmbH <info@tracetronic.de>
 *
 * SPDX-License-Identifier: BSD-3-Clause
 */

/*
=============
Prerequisites
=============
* Maven tool installation configured as M3
* JDK tool installation configured as JDK17
* Global environment variable EMAIL_RECIPIENTS set
* Jenkins plugins installed:
- https://plugins.jenkins.io/jacoco
- https://plugins.jenkins.io/javadoc
- https://plugins.jenkins.io/timestamper
- https://plugins.jenkins.io/warnings-ng
*/

@Library(['tracetronic-jenkins-lib', 'internal-cxs-jenkins-lib']) _

pipeline {
    options {
        buildDiscarder(logRotator(daysToKeepStr: '14'))
        timestamps()
    }
    agent any
    environment {
        authKey = credentials('TG_authkey_test_report_upload')
        pipeline_report_dir = "report2TG/build-$env.BUILD_NUMBER"
        PRODUCT_NAME = "ecutest-plugin"
        PRODUCT_VERSION = readMavenPom().getVersion()
        TEST_LEVEL = "unit"
    }
    tools {
        maven 'M3'
    }
    stages {
        stage('Build') {
            steps {
                mvn 'clean package -DskipUTs'
                archiveArtifacts artifacts: 'target/*.hpi', fingerprint: true
            }
        }
        stage('Static Code Analysis') {
            steps {
                mvn 'checkstyle:check pmd:check pmd:cpd-check spotbugs:check'
                recordIssues(tools: [
                    checkStyle(pattern: 'target/checkstyle-result.xml'),
                    pmdParser(pattern: 'target/pmd.xml'),
                    cpd(pattern: 'target/cpd.xml'),
                    spotBugs(pattern: 'target/spotbugsXml.xml', useRankAsPriority: true),
                    taskScanner(includePattern: 'src/**/*.java', normalTags: 'TODO', highTags: 'FIXME')])
            }
        }
        stage('Unit Tests') {
            steps {
                mvn 'jacoco:prepare-agent surefire:test -Dsurefire.useFile=false'
                junit 'target/surefire-reports/TEST-*.xml'
                Xml2TG((long) currentBuild.startTimeInMillis, "target/surefire-reports", "JUnit","uploadJson", [:], [:], "${TESTGUIDE_url}", "${authKey}", "${TESTGUIDE_projectID}")
                jacoco exclusionPattern: '**/Messages.class', execPattern: 'target/jacoco.exec'
            }
        }
        stage('Docs') {
            steps {
                mvn 'javadoc:javadoc'
                step([$class: 'JavadocArchiver', javadocDir: 'target/reports/apidocs', keepAll: false])
            }
        }
    }
    post {
        always {
            dir("${pipeline_report_dir}") {
                pipeline2ATX(true)
            }
            uploadJson2TG("${TESTGUIDE_url}", "${authKey}", "${TESTGUIDE_projectID}", "${pipeline_report_dir}/**", '')
        }
        unsuccessful {
            mail to: "${env.EMAIL_RECIPIENTS}",
                subject: "${JOB_NAME} - Build #${BUILD_NUMBER} - ${currentBuild.currentResult}",
                body: "Check console output at ${BUILD_URL} to view the results."
        }
    }
}

def mvn(def args) {
    def mvnHome = tool 'M3'
    def javaHome = tool 'JDK17'
    withEnv(["JAVA_HOME=${javaHome}", "PATH+MAVEN=${mvnHome}/bin:${env.JAVA_HOME}/bin"]) {
        if (isUnix()) {
            sh "${mvnHome}/bin/mvn ${args} -B -V -U -e"
        } else {
            bat "${mvnHome}\\bin\\mvn ${args} -B -V -U -e"
        }
    }
}