configure.ac

#
# Project Wok
#
# Copyright IBM Corp, 2013-2017
#
# Code derived from Project Kimchi
#
# This library is free software; you can redistribute it and/or
# modify it under the terms of the GNU Lesser General Public
# License as published by the Free Software Foundation; either
# version 2.1 of the License, or (at your option) any later version.
#
# This library is distributed in the hope that it will be useful,
# but WITHOUT ANY WARRANTY; without even the implied warranty of
# MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
# Lesser General Public License for more details.
#
# You should have received a copy of the GNU Lesser General Public
# License along with this library; if not, write to the Free Software
# Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA  02110-1301  USA

AC_INIT([wok], [m4_esyscmd([./build-aux/pkg-version --version])])

AC_SUBST([PACKAGE_VERSION],
         [m4_esyscmd([./build-aux/pkg-version --version])])

AC_SUBST([PACKAGE_RELEASE],
         [m4_esyscmd([./build-aux/pkg-version --release])])

AC_CONFIG_COMMANDS([generate_deps], [./build-aux/generateDepsFiles.py])

AC_SUBST_FILE([DEBIAN_DEPS])
DEBIAN_DEPS=./build-aux/debian-pkg-deps

AC_SUBST_FILE([UBUNTU_DEPS])
UBUNTU_DEPS=./build-aux/ubuntu-pkg-deps

AC_SUBST_FILE([FEDORA_DEPS])
FEDORA_DEPS=./build-aux/fedora-pkg-deps

AC_SUBST_FILE([SUSE_DEPS])
SUSE_DEPS=./build-aux/opensuse-leap-pkg-deps

# Testing for version and release
AS_IF([test "x$PACKAGE_VERSION" = x],
      AC_MSG_ERROR([package version not defined]))
AS_IF([test "x$PACKAGE_RELEASE" = x],
      AC_MSG_ERROR([package release not defined]))

AC_CONFIG_AUX_DIR([build-aux])
AM_INIT_AUTOMAKE([-Wno-portability])
AM_PATH_PYTHON([3.6])
AC_PATH_PROG([PEP8], [pep8], [/usr/bin/pep8])
AC_PATH_PROG([GIT], [git], [/usr/bin/git])
AC_PATH_PROG([RPMLINT], [rpmlint], [/usr/bin/rpmlint])
AC_PYTHON_MODULE([unittest])
AC_SUBST([HAVE_PYMOD_UNITTEST])
AC_SUBST([PYTHON_VERSION])
AM_GNU_GETTEXT([external])
AM_GNU_GETTEXT_VERSION([0.10])
AC_PATH_PROG([CHEETAH], [cheetah], [/usr/bin/cheetah])
AC_SUBST([pythondir],
         [m4_esyscmd([python3 -c "import distutils.sysconfig as sys; print(sys.get_python_lib())"])])

# Checking for pyflakes
AC_PATH_PROG([PYFLAKES], [pyflakes])
if test "x$PYFLAKES" = "x"; then
  AC_MSG_WARN([pyflakes not found])
fi

# check for systemd
PKG_PROG_PKG_CONFIG
AC_ARG_WITH([systemdsystemunitdir],
    AS_HELP_STRING([--with-systemdsystemunitdir=DIR], [Directory for systemd service files]),
    [], [with_systemdsystemunitdir=$($PKG_CONFIG --variable=systemdsystemunitdir systemd)])
if test "x$with_systemdsystemunitdir" != xno; then
    AC_SUBST([systemdsystemunitdir], [$with_systemdsystemunitdir])
fi

AC_CONFIG_FILES([
    po/Makefile.in
    po/gen-pot
    Makefile
    docs/Makefile
    docs/wokd.8
    docs/API/Makefile
    src/Makefile
    src/nginx/Makefile
    src/wok/Makefile
    src/wok/control/Makefile
    src/wok/model/Makefile
    src/wok/xmlutils/Makefile
    src/wok/plugins/Makefile
    ui/Makefile
    ui/css/Makefile
    ui/images/Makefile
    ui/images/theme-default/Makefile
    ui/js/Makefile
    ui/libs/Makefile
    ui/libs/jquery-containsNC/Makefile
    ui/pages/Makefile
    ui/pages/help/Makefile
    ui/pages/tabs/Makefile
    ui/pages/help/en_US/Makefile
    ui/config/Makefile
    contrib/Makefile
    contrib/DEBIAN/Makefile
    contrib/DEBIAN/control.debian
    contrib/DEBIAN/control.ubuntu
    contrib/wok.spec.fedora
    contrib/wok.spec.suse
    tests/Makefile
],[
    chmod +x po/gen-pot
])

AC_OUTPUT