Merge pull request #33 from bertbaron/main

feat: highlight query file

queries/highlights.scm

@@ -0,0 +1,114 @@
+(identifier) @variable
+
+(import_stmt
+  (dotted_name
+    (identifier) @namespace))
+
+(import_stmt
+  (dotted_name
+    (identifier) @namespace)
+  (identifier) @namespace)
+
+(basic_type) @type
+
+(schema_type
+  (dotted_name
+    (identifier) @type))
+
+(schema_type
+  (dotted_name
+    (identifier) @namespace
+    (identifier) @type))
+
+(schema_expr
+  (identifier) @type)
+
+(protocol_stmt
+  (identifier) @type)
+
+(rule_stmt
+    (identifier) @type)
+
+(schema_stmt
+  (identifier) @type)
+
+(lambda_expr
+  (typed_parameter (identifier) @parameter))
+
+(lambda_expr
+  (identifier) @parameter)
+
+(selector_expr
+  (select_suffix
+    (identifier) @property))
+
+(comment) @comment
+(string) @string
+(escape_sequence) @escape
+
+(call_expr
+    (identifier) @function)
+
+[
+  (integer)
+  (float)
+] @number
+
+[
+  (true)
+  (false)
+  (none) 
+  (undefined)
+] @constant.builtin
+
+[
+  "all"
+  "any"
+  "assert"
+  "as"
+  "check"
+  "elif"
+  "else"
+  "filter"
+  "for"
+  "if"
+  "import"
+  "lambda"
+  "map"
+  "mixin"
+  "protocol"
+  "rule"
+  "schema"
+  "type"
+] @keyword
+
+[
+  "+"
+  "-"
+  "*"
+  "**"
+  "/"
+  "//"
+  "%"
+  "<<"
+  ">>"
+  "&"
+  "|"
+  "^"
+  "<"
+  ">"
+  "~"
+  "<="
+  ">="
+  "=="
+  "!="
+  "@"
+;  "\\"
+  "and"
+  "or"
+  "not"
+  "in"
+  "is"
+  "="
+  ":"
+] @operator

test/highlight/import.k

@@ -0,0 +1,24 @@
+import regex
+# ^ keyword
+#        ^ namespace
+
+import regex.v1
+# ^ keyword
+#        ^ namespace
+#            ^ namespace
+
+import regex as rxp
+# ^ keyword
+#        ^ namespace
+#            ^ keyword
+#                ^ namespace
+
+import regex.v1 as rxp
+# ^ keyword
+#        ^ namespace
+#               ^ keyword
+#                   ^ namespace
+
+import ...regex
+# ^ keyword
+#           ^ namespace

test/highlight/lambda.k

@@ -0,0 +1,12 @@
+lambda fullname: Person, lastname {
+# ^ keyword
+#        ^ parameter
+#                 ^ type
+#                          ^ parameter
+    x.name + " " + str(lastname)
+    # <- variable
+    #  ^ property
+    #        ^ string
+    #               ^ function
+    #                     ^ variable
+}

test/highlight/literal.k

@@ -0,0 +1,15 @@
+33
+# <- number
+
+3.14
+# <- number
+
+"all"
+# <- string
+
+{
+    key = value
+    # <- variable
+    #   ^ operator
+    #       ^ variable
+}

test/highlight/schema.k

@@ -0,0 +1,23 @@
+schema Person:
+#^ @keyword
+#        ^ type
+    age: str = 33
+    # ^ variable
+    #     ^ type
+    #          ^ number
+
+protocol DataProtocol:
+#^ @keyword
+#         ^ type
+    data: str
+    # ^ variable
+    #     ^ type
+
+rule SomeRule:
+#^ @keyword
+#      ^ type
+    age > 0, "rule check failure message"
+    # ^ variable
+    #   ^ operator
+    #     ^ number
+    #         ^ string

test/highlight/type.k

@@ -0,0 +1,18 @@
+a: int
+# <- variable
+#   ^ type
+
+b: float
+#   ^ type
+
+c: bool
+#   ^ type
+
+d: str
+#   ^ type
+
+e: None
+#   ^ type
+
+f: Undefined
+#   ^ type