refact(Android): convert example apps Groovy scripts to Kotlin

Example/android/app/build.gradle → Example/android/app/build.gradle.kts

@@ -1,6 +1,10 @@
-apply plugin: "com.android.application"
-apply plugin: "org.jetbrains.kotlin.android"
-apply plugin: "com.facebook.react"
+import groovy.lang.Closure
+
+plugins {
+    id ("com.android.application")
+    id ("org.jetbrains.kotlin.android")
+    id ("com.facebook.react")
+}
 
 /**
  * This is the configuration block to customize your React Native Android app.
@@ -54,7 +58,7 @@ react {
 /**
  * Set this to true to Run Proguard on Release builds to minify the Java bytecode
  */
-def enableProguardInReleaseBuilds = false
+val enableProguardInReleaseBuilds = false
 
 /**
  * The preferred build flavor of JavaScriptCore (JSC)
@@ -67,71 +71,71 @@ def enableProguardInReleaseBuilds = false
  * give correct results when using with locales other than en-US. Note that
  * this variant is about 6MiB larger per architecture than default.
  */
-def jscFlavor = 'org.webkit:android-jsc:+'
+val jscFlavor = "org.webkit:android-jsc:+"
 
 android {
-    ndkVersion rootProject.ext.ndkVersion
-
-    buildToolsVersion rootProject.ext.buildToolsVersion
-    compileSdk rootProject.ext.compileSdkVersion
-
-    namespace "com.swmansion.rnscreens.example"
+    ndkVersion = rootProject.extra["ndkVersion"] as String
+    compileSdk = rootProject.extra["compileSdkVersion"] as Int
+    namespace = "com.swmansion.rnscreens.example"
     defaultConfig {
-        applicationId "com.swmansion.rnscreens.example"
-        minSdkVersion rootProject.ext.minSdkVersion
-        targetSdkVersion rootProject.ext.targetSdkVersion
-        versionCode 1
-        versionName "1.0"
-        testBuildType System.getProperty('testBuildType', 'release')
-        testInstrumentationRunner 'androidx.test.runner.AndroidJUnitRunner'
+        applicationId = "com.swmansion.rnscreens.example"
+        minSdkVersion(rootProject.extra["minSdkVersion"] as Int)
+        targetSdkVersion(rootProject.extra["targetSdkVersion"] as Int)
+        versionCode = 1
+        versionName = "1.0"
+        testBuildType = System.getProperty("testBuildType", "release")
+        testInstrumentationRunner = "androidx.test.runner.AndroidJUnitRunner"
     }
     signingConfigs {
-        debug {
-            storeFile file('debug.keystore')
-            storePassword 'android'
-            keyAlias 'androiddebugkey'
-            keyPassword 'android'
+        getByName("debug") {
+            storeFile = file("debug.keystore")
+            storePassword = "android"
+            keyAlias = "androiddebugkey"
+            keyPassword = "android"
         }
-        release {
-            storeFile file("rns-example-keystore.jks")
-            storePassword "12345678"
-            keyAlias "react-native-screens-example"
-            keyPassword "12345678"
+        create("release") {
+            storeFile = file("rns-example-keystore.jks")
+            storePassword = "12345678"
+            keyAlias = "react-native-screens-example"
+            keyPassword = "12345678"
         }
     }
     buildTypes {
-        debug {
-            signingConfig signingConfigs.debug
+        getByName("debug") {
+            signingConfig = signingConfigs.getByName("debug")
         }
-        release {
+        getByName("release") {
             // Caution! In production, you need to generate your own keystore file.
             // see https://reactnative.dev/docs/signed-apk-android.
-            minifyEnabled enableProguardInReleaseBuilds
-            proguardFiles getDefaultProguardFile("proguard-android.txt"), "proguard-rules.pro"
+            isMinifyEnabled = enableProguardInReleaseBuilds
+            proguardFiles(getDefaultProguardFile("proguard-android.txt"), "proguard-rules.pro")
 
-            signingConfig signingConfigs.release
+            signingConfig = signingConfigs.getByName("release")
             // Detox-specific additions to pro-guard
-            proguardFile "${rootProject.projectDir}/../node_modules/detox/android/detox/proguard-rules-app.pro"
+            proguardFile("${rootProject.projectDir}/../node_modules/detox/android/detox/proguard-rules-app.pro")
         }
     }
 }
+val hermesEnabled: String by project
 
 dependencies {
-    androidTestImplementation('com.wix:detox:+') {
+    androidTestImplementation("com.wix:detox:+") {
         // Both rn-screens and detox are using this class
         // https://github.com/wix/Detox/issues/2848
-        exclude group: 'com.google.android.material'
+        exclude(group = "com.google.android.material")
     }
-    implementation "androidx.appcompat:appcompat:1.6.1"
-  
+    implementation("androidx.appcompat:appcompat:1.6.1")
+
     // The version of react-native is set by the React Native Gradle Plugin
     implementation("com.facebook.react:react-android")
 
     if (hermesEnabled.toBoolean()) {
         implementation("com.facebook.react:hermes-android")
     } else {
-        implementation jscFlavor
+        implementation(jscFlavor)
     }
 }
 
-apply from: file("../../node_modules/@react-native-community/cli-platform-android/native_modules.gradle"); applyNativeModulesAppBuildGradle(project)
+apply (from = "../../node_modules/@react-native-community/cli-platform-android/native_modules.gradle")
+val applyNativeModules: Closure<Any> = extra.get("applyNativeModulesAppBuildGradle") as Closure<Any>
+applyNativeModules(project)

Example/android/app/proguard-rules.pro

@@ -2,7 +2,7 @@
 # By default, the flags in this file are appended to flags specified
 # in /usr/local/Cellar/android-sdk/24.3.3/tools/proguard/proguard-android.txt
 # You can edit the include path and order by changing the proguardFiles
-# directive in build.gradle.
+# directive in build.gradle.kts.
 #
 # For more details, see
 #   http://developer.android.com/guide/developing/tools/proguard.html

Example/android/build.gradle → Example/android/build.gradle.kts

@@ -1,12 +1,10 @@
 buildscript {
-    ext {
-        buildToolsVersion = "34.0.0"
-        minSdkVersion = 23
-        compileSdkVersion = 34
-        targetSdkVersion = 34
-        ndkVersion = "26.1.10909125"
-        kotlinVersion = "1.9.22"
-    }
+    val buildToolsVersion: String by extra("34.0.0")
+    val compileSdkVersion: Int by extra(34)
+    val minSdkVersion: Int by extra(23)
+    val targetSdkVersion: Int by extra(34)
+    val ndkVersion: String by extra("26.1.10909125")
+    val kotlinVersion: String by extra("1.9.22")
     repositories {
         google()
         mavenCentral()
@@ -26,9 +24,9 @@ buildscript {
 allprojects {
     repositories {
         maven {
-            url("$rootDir/../node_modules/detox/Detox-android")
+            url = uri("$rootDir/../node_modules/detox/Detox-android")
         }
     }
 }
 
-apply plugin: "com.facebook.react.rootproject"
+apply (plugin= "com.facebook.react.rootproject")

Example/android/settings.gradle.kts

@@ -0,0 +1,8 @@
+import groovy.lang.Closure
+
+rootProject.name = "ScreensExample"
+apply(from = "../node_modules/@react-native-community/cli-platform-android/native_modules.gradle")
+val applyNativeModules: Closure<Any> = extra.get("applyNativeModulesSettingsGradle") as Closure<Any>
+applyNativeModules(settings)
+include(":app")
+includeBuild("../node_modules/@react-native/gradle-plugin")

FabricTestExample/android/app/build.gradle → FabricExample/android/app/build.gradle.kts

@@ -1,6 +1,10 @@
-apply plugin: "com.android.application"
-apply plugin: "org.jetbrains.kotlin.android"
-apply plugin: "com.facebook.react"
+import groovy.lang.Closure
+
+plugins {
+    id ("com.android.application")
+    id ("com.facebook.react")
+    id ("org.jetbrains.kotlin.android")
+}
 
 /**
  * This is the configuration block to customize your React Native Android app.
@@ -54,7 +58,7 @@ react {
 /**
  * Set this to true to Run Proguard on Release builds to minify the Java bytecode.
  */
-def enableProguardInReleaseBuilds = false
+val enableProguardInReleaseBuilds = false
 
 /**
  * The preferred build flavor of JavaScriptCore (JSC)
@@ -67,42 +71,43 @@ def enableProguardInReleaseBuilds = false
  * give correct results when using with locales other than en-US. Note that
  * this variant is about 6MiB larger per architecture than default.
  */
-def jscFlavor = 'org.webkit:android-jsc:+'
+val jscFlavor = "org.webkit:android-jsc:+"
 
 android {
-    ndkVersion rootProject.ext.ndkVersion
-    buildToolsVersion rootProject.ext.buildToolsVersion
-    compileSdk rootProject.ext.compileSdkVersion
+    ndkVersion = rootProject.extra["ndkVersion"] as String
+    buildToolsVersion = rootProject.extra["buildToolsVersion"] as String
+    compileSdk = rootProject.extra["compileSdkVersion"] as Int
 
-    namespace "com.fabrictestexample"
+    namespace = "com.fabricexample"
     defaultConfig {
-        applicationId "com.fabrictestexample"
-        minSdkVersion rootProject.ext.minSdkVersion
-        targetSdkVersion rootProject.ext.targetSdkVersion
-        versionCode 1
-        versionName "1.0"
+        applicationId = "com.fabricexample"
+        minSdkVersion(rootProject.extra["minSdkVersion"] as Int)
+        targetSdkVersion(rootProject.extra["targetSdkVersion"] as Int)
+        versionCode = 1
+        versionName = "1.0"
     }
     signingConfigs {
-        debug {
-            storeFile file('debug.keystore')
-            storePassword 'android'
-            keyAlias 'androiddebugkey'
-            keyPassword 'android'
+        getByName("debug") {
+            storeFile = file("debug.keystore")
+            storePassword = "android"
+            keyAlias = "androiddebugkey"
+            keyPassword = "android"
         }
     }
     buildTypes {
-        debug {
-            signingConfig signingConfigs.debug
+        getByName("debug") {
+            signingConfig = signingConfigs.getByName("debug")
         }
-        release {
+        getByName("release") {
             // Caution! In production, you need to generate your own keystore file.
             // see https://reactnative.dev/docs/signed-apk-android.
-            signingConfig signingConfigs.debug
-            minifyEnabled enableProguardInReleaseBuilds
-            proguardFiles getDefaultProguardFile("proguard-android.txt"), "proguard-rules.pro"
+            signingConfig = signingConfigs.getByName("debug")
+            isMinifyEnabled = enableProguardInReleaseBuilds
+            proguardFiles(getDefaultProguardFile("proguard-android.txt"), "proguard-rules.pro")
         }
     }
 }
+val hermesEnabled: String by project
 
 dependencies {
     // The version of react-native is set by the React Native Gradle Plugin
@@ -111,8 +116,10 @@ dependencies {
     if (hermesEnabled.toBoolean()) {
         implementation("com.facebook.react:hermes-android")
     } else {
-        implementation jscFlavor
+        implementation(jscFlavor)
     }
 }
 
-apply from: file("../../node_modules/@react-native-community/cli-platform-android/native_modules.gradle"); applyNativeModulesAppBuildGradle(project)
+apply (from = "../../node_modules/@react-native-community/cli-platform-android/native_modules.gradle")
+val applyNativeModules: Closure<Any> = extra.get("applyNativeModulesAppBuildGradle") as Closure<Any>
+applyNativeModules(project)

FabricExample/android/app/proguard-rules.pro

@@ -2,7 +2,7 @@
 # By default, the flags in this file are appended to flags specified
 # in /usr/local/Cellar/android-sdk/24.3.3/tools/proguard/proguard-android.txt
 # You can edit the include path and order by changing the proguardFiles
-# directive in build.gradle.
+# directive in build.gradle.kts.
 #
 # For more details, see
 #   http://developer.android.com/guide/developing/tools/proguard.html

FabricExample/android/build.gradle.kts

@@ -0,0 +1,21 @@
+buildscript {
+    extra.apply {
+        set("buildToolsVersion", "34.0.0")
+        set("minSdkVersion", 23)
+        set("compileSdkVersion", 34)
+        set("targetSdkVersion", 34)
+        set("ndkVersion", "26.1.10909125")
+        set("kotlinVersion", "1.9.22")
+    }
+    repositories {
+        google()
+        mavenCentral()
+    }
+    dependencies {
+        classpath("com.android.tools.build:gradle")
+        classpath("com.facebook.react:react-native-gradle-plugin")
+        classpath("org.jetbrains.kotlin:kotlin-gradle-plugin")
+    }
+}
+
+apply(plugin = "com.facebook.react.rootproject")

FabricExample/android/settings.gradle.kts

@@ -0,0 +1,8 @@
+import groovy.lang.Closure
+
+rootProject.name = "FabricExample"
+apply(from = "../node_modules/@react-native-community/cli-platform-android/native_modules.gradle")
+val applyNativeModules: Closure<Any> = extra.get("applyNativeModulesSettingsGradle") as Closure<Any>
+applyNativeModules(settings)
+include(":app")
+includeBuild("../node_modules/@react-native/gradle-plugin")